#################################################
#
#  (C) 2019 Slávek Banko
#  slavek.banko (AT) axis.cz
#
#  Improvements and feedback are welcome
#
#  This file is released under GPL >= 2
#
#################################################


##### set project version ########################

include( TDEVersion )
cmake_minimum_required( VERSION ${TDE_CMAKE_MINIMUM_VERSION} )


##### include our cmake modules #################

include( TDEL10n )


##### create translation template for desktop files #####

tde_l10n_create_template(
    CATALOG "desktop_files/kvirc-desktops"
    SOURCES *.desktop *.mime *.protocol
)


##### force to use standard xgettext ############

set( __bak_KDE_XGETTEXT_EXECUTABLE ${KDE_XGETTEXT_EXECUTABLE} )
set( KDE_XGETTEXT_EXECUTABLE "${XGETTEXT_EXECUTABLE}" )


##### create translation templates ##############

tde_l10n_create_template(
    CATALOG "kvirc"
    SOURCES
        "src"
        "data/defscript/*.kvs"
    KEYWORDS
        - i18n:1c,2
        __tr __tr_no_lookup __tr2qs __tr2qs_ctrl __tr2wc __tr2ws tr
    X-POT -
    DESTINATION "translations/messages/kvirc"
)

file( GLOB _modules
      RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}/src/modules
      "${CMAKE_CURRENT_SOURCE_DIR}/src/modules/*"
)
foreach( _module ${_modules} )
    if( IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/translations/messages/kvirc-${_module} AND
        IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/src/modules/${_module} )

        tde_l10n_create_template(
            CATALOG "kvirc-${_module}"
            SOURCES
                "src/modules/${_module}"
            KEYWORDS
                - i18n:1c,2
                __tr_ctx __tr_no_lookup_ctx __tr_no_lookup
                __tr2qs_ctx __tr2qs_ctrl_ctx __tr2wc_ctx __tr2ws_ctx __tr2qs_no_lookup
            X-POT -
            DESTINATION "translations/messages/kvirc-${_module}"
        )
    endif( )
endforeach( )


##### restore kde-xgettext ######################

set( KDE_XGETTEXT_EXECUTABLE "${__bak_KDE_XGETTEXT_EXECUTABLE}" )
unset( __bak_KDE_XGETTEXT_EXECUTABLE )
